VARIABLE = "value"

In this example, VARIABLE is value.

BitBake supports variables referencing one another's contents using a syntax which is similar to shell scripting

A = "aval"
B = "pre${A}post"

This results in A containing aval and B containing preavalpost.

A ?= "aval"

If A is set before the above is called, it will retain its previous value. If A is unset prior to the above call, A will be set to aval. Note that this assignment is immediate, so if there are multiple ?= assignments to a single variable, the first of those will be used.

A ??= "somevalue"
A ??= "someothervalue"

If A is set before the above, it will retain that value. If A is unset prior to the above, A will be set to someothervalue. This is a lazy/weak assignment in that the assignment does not occur until the end of the parsing process, so that the last, rather than the first, ??= assignment to a given variable will be used. Any other setting of A using = or ?= will however override the value set with ??=

:= results in a variable's contents being expanded immediately, rather than when the variable is actually used.

T = "123"
A := "${B} ${A} test ${T}"
T = "456"
B = "${T} bval"

C = "cval"
C := "${C}append"

In that example, A would contain test 123, B would contain 456 bval, and C would be cvalappend.

B = "bval"
B += "additionaldata"
C = "cval"
C =+ "test"

In this example, B is now bval additionaldata and C is test cval.

B = "bval"
B .= "additionaldata"
C = "cval"
C =. "test"

In this example, B is now bvaladditionaldata and C is testcval. In contrast to the above appending and prepending operators, no additional space will be introduced.

OVERRIDES is a “:” separated variable containing each item you want to satisfy conditions. So, if you have a variable which is conditional on “arm”, and “arm” is in OVERRIDES, then the “arm” specific version of the variable is used rather than the non-conditional version. Example:

OVERRIDES = "architecture:os:machine"
TEST = "defaultvalue"
TEST_os = "osspecificvalue"
TEST_condnotinoverrides = "othercondvalue"

In this example, TEST would be osspecificvalue, due to the condition “os” being in OVERRIDES.

BitBake also supports appending and prepending to variables based on whether something is in OVERRIDES. Example:

DEPENDS = "glibc ncurses"
OVERRIDES = "machine:local"
DEPENDS_append_machine = " libmad"

In this example, DEPENDS is set to glibc ncurses libmad.

Next, there is the include directive, which causes BitBake to parse whatever file you specify, and insert it at that location, which is not unlike make. However, if the path specified on the include line is a relative path, BitBake will locate the first one it can find within BBPATH.

In contrast to the include directive, require will raise an ParseError if the file to be included cannot be found. Otherwise it will behave just like the include directive.

DATE = "${@time.strftime('%Y%m%d',time.gmtime())}"

This would result in the DATE variable containing today's date.

NOTE: This is only supported in .bb and .bbclass files.

do_mytask () {
    echo "Hello, world!"
}

This is essentially identical to setting a variable, except that this variable happens to be executable shell code.

python do_printdate () {
    import time
    print time.strftime('%Y%m%d', time.gmtime())
}

This is the similar to the previous, but flags it as Python so that BitBake knows it is Python code.

NOTE: This is only supported in .bb and .bbclass files.

def get_depends(bb, d):
    if d.getVar('SOMECONDITION', True):
        return "dependencywithcond"
    else:
        return "dependency"

SOMECONDITION = "1"
DEPENDS = "${@get_depends(bb, d)}"

This would result in DEPENDS containing dependencywithcond.

Variables can have associated flags which provide a way of tagging extra information onto a variable. Several flags are used internally by BitBake but they can be used externally too if needed. The standard operations mentioned above also work on flags.

VARIABLE[SOMEFLAG] = "value"

In this example, VARIABLE has a flag, SOMEFLAG which is set to value.

NOTE: This is only supported in .bb and .bbclass files.

The inherit directive is a means of specifying what classes of functionality your .bb requires. It is a rudimentary form of inheritance. For example, you can easily abstract out the tasks involved in building a package that uses autoconf and automake, and put that into a bbclass for your packages to make use of. A given bbclass is located by searching for classes/filename.bbclass in BBPATH, where filename is what you inherited.

NOTE: This is only supported in .bb and .bbclass files.

In BitBake, each step that needs to be run for a given .bb is known as a task. There is a command addtask to add new tasks (must be a defined Python executable metadata and must start with “do_”) and describe intertask dependencies.

python do_printdate () {
    import time
    print time.strftime('%Y%m%d', time.gmtime())
}

addtask printdate before do_build

This defines the necessary Python function and adds it as a task which is now a dependency of do_build, the default task. If anyone executes the do_build task, that will result in do_printdate being run first.

Tasks support a number of flags which control various functionality of the task. These are as follows:

'dirs' - directories which should be created before the task runs

'cleandirs' - directories which should created before the task runs but should be empty

'noexec' - marks the tasks as being empty and no execution required. These are used as dependency placeholders or used when added tasks need to be subsequently disabled.

'nostamp' - don't generate a stamp file for a task. This means the task is always rexecuted.

'fakeroot' - this task needs to be run in a fakeroot environment, obtained by adding the variables in FAKEROOTENV to the environment.

'umask' - the umask to run the task under.

For the 'deptask', 'rdeptask', 'depends', 'rdepends' and 'recrdeptask' flags please see the dependencies section.

NOTE: This is only supported in .bb and .bbclass files.

BitBake allows installation of event handlers. Events are triggered at certain points during operation, such as the beginning of operation against a given .bb, the start of a given task, task failure, task success, et cetera. The intent is to make it easy to do things like email notification on build failure.

addhandler myclass_eventhandler
python myclass_eventhandler() {
    from bb.event import getName
    from bb import data

    print("The name of the Event is %s" % getName(e))
    print("The file we run for is %s" % data.getVar('FILE', e.data, True))
}

This event handler gets called every time an event is triggered. A global variable e is defined. e.data contains an instance of bb.data. With the getName(e) method one can get the name of the triggered event.

The above event handler prints the name of the event and the content of the FILE variable.

Two BitBake features exist to facilitate the creation of multiple buildable incarnations from a single recipe file.

The first is BBCLASSEXTEND. This variable is a space separated list of classes used to "extend" the recipe for each variant. As an example, setting

BBCLASSEXTEND = "native"

results in a second incarnation of the current recipe being available. This second incarnation will have the "native" class inherited.

The second feature is BBVERSIONS. This variable allows a single recipe to build multiple versions of a project from a single recipe file, and allows you to specify conditional metadata (using the OVERRIDES mechanism) for a single version, or an optionally named range of versions:

BBVERSIONS = "1.0 2.0 git"
SRC_URI_git = "git://someurl/somepath.git"

BBVERSIONS = "1.0.[0-6]:1.0.0+ \
              1.0.[7-9]:1.0.7+"
SRC_URI_append_1.0.7+ = "file://some_patch_which_the_new_versions_need.patch;patch=1"

Note that the name of the range will default to the original version of the recipe, so given OE, a recipe file of foo_1.0.0+.bb will default the name of its versions to 1.0.0+. This is useful, as the range name is not only placed into overrides; it's also made available for the metadata to use in the form of the BPV variable, for use in file:// search paths (FILESPATH).